model-lang/docs/modellang.bnf

<model>  ::=
    <statement> ";" <model>
    | <statement>

<statement> ::=
    <system>
    | <behavior>
    | <interaction>
    | <trigger>
    | <init>

<system> ::= "SYSTEM" <systemId> "=" <definitionPattern>
<behavior> ::= "BEHAVIOR" <behaviorId> "=" <definitionPattern>
<interaction> ::= "INTERACTION" <interactionBody>
<trigger> ::= "WHEN" <selectionPatternSans> <codeBlock>
<init> ::= "INIT" <systemId> <codeBlock> | "INIT" <codeBlock>

<definitionPattern> ::=
    <alternation>
    | <sequence>

<alternation> ::=
    <element> "|" <alternation>
    | <element> "|" <element>

<sequence> ::=
    <element> <sequence>
    | <element>

<element> ::=
    "(" <definitionPattern> ")" <quantifier>
    | <event> <quantifier>

<event> ::=
    <identifier>

<quantifier> ::=
    "*"
    | "+"
    | "?"
    | "{" integer "}"
    | "{" integer "," "}"
    | "{" integer "," integer "}"
    | empty

<interactionBody> ::=
    <interactionJoin>
    | <interactionThen>

<interactionJoin> ::=
    <selectionPatternSans> <join> <interactionJoin>
    | <selectionPatternSans> <join> <selectionPatternSans>

<interactionThen> ::=
    <selectionPattern> <then> <interactionThen>
    | <selectionPattern> <then> <selectionPattern>

<selectionPattern> ::=
    <codeBlock> <systemId> ":" <definitionPattern> <codeBlock>
    | <systemId> ":" <definitionPattern> <codeBlock>
    | <codeBlock> <systemId> ":" <definitionPattern>
    | <selectionPatternSans>

<selectionPatternSans> ::=
    <systemId> ":" <definitionPattern>

<join> ::=
    "=="

<then> ::=
    "->"

<codeBlock> ::=
    "{" text <codeBlock> text "}"
    | "{" text "}"

<systemId> ::= <identifier>
<behaviorId> ::= <identifier>
<identifier> ::= alphanumString